MODULE.bazel

# Foundational packages

http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_file = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")

wine_wmc_repository = use_repo_rule("//bazel/tools/wmc:wine_wmc.bzl", "wine_wmc_repository")

env_vars = use_repo_rule("//bazel/repo:env_vars.bzl", "env_vars")

# Environment values available for packaging.
env_vars(
    name = "agent_volatile",
    # Each variable needs a justification. Every time you use one, the
    # target using it is potentially uncachable.
    # ⚠️ Keep in sync with the `--repo_env=` entries in .bazelrc
    variables = [
        # Stamps pkg/version.{Commit,FullCommit}, only in builds that also set
        # PACKAGE_VERSION, so other CI jobs keep caching across commits.
        "CI_COMMIT_SHA",
        # This gets set by omnibus builds in many cases. It's used in the script
        # to set things like compression, so we'll mimic that for now.
        "DEPLOY_AGENT",
        # For some tests we want to run with higher compression, but
        # not break caching and rebuild the binaries.
        "FORCED_PACKAGE_COMPRESSION_LEVEL",
        # Lets a caller force pkg/version.AgentVersion to an explicit value,
        # overriding the PACKAGE_VERSION/release.json-derived default.
        # Used by host-profiler's nightly/dev-branch version override.
        "FORCE_AGENT_VERSION",
        # This is the build pipeline id, which is used in some symlink paths.
        "PACKAGE_VERSION",
        # macOS code signing: control whether to enable code signing
        "SIGN_MAC",
    ],
)

# Expose release.json for information about the current release.
release_json = use_repo_rule("//bazel/repo:release_json.bzl", "release_json")

release_json(name = "dd_release_json")

# Instead of the canonical rules_license, we use the version from supply-chain.
# This allows mixing both old and new license rules during the multi-year
# migration between the two styles. The rules_license overlay will never be
# available in the BCR, for obvious name confusion reasons, so we have to
# use an archive_override to pull the alternate reality from supply-chain.

# Do not update any of these individually. They are essentially a hand matched set as of Q3 2026.
# That will improve over the next year.
bazel_dep(name = "package_metadata", version = "0.0.13")
bazel_dep(name = "rules_license", version = "1.0.0")
bazel_dep(name = "supply_chain_tools", version = "0.0.3")
bazel_dep(name = "supply-chain-go", version = "0.0.7")

# We are temporarily using a development fork which is ahead of the release.
archive_override(
    module_name = "rules_license",
    sha256 = "d843315c777a0296a40c22e5189b576e9944f6f4b377fe438ebf6d1e21e794eb",
    strip_prefix = "supply-chain-dd_test/rules_license",
    urls = ["https://github.com/aiuto/supply-chain/archive/refs/tags/dd_test.tar.gz"],
)

# The BCR is currently behind the releases.
archive_override(
    module_name = "supply_chain_tools",
    sha256 = "6293f766876344104a20083239785133218322ce28aac0b43040bc5479f5a513",
    strip_prefix = "supply_chain_tools-0.0.3/tools",
    url = "https://github.com/bazel-contrib/supply-chain/releases/download/supply_chain_tools-0.0.3/supply_chain_tools-0.0.3.tar.gz",
)

# The BCR is currently behind the releases.
archive_override(
    module_name = "supply-chain-go",
    sha256 = "894732fdd78ef741da586152e196acf8a72d9542e35dac1810f96a9d640ae6cd",
    strip_prefix = "supply-chain-go-0.0.11/lib/supplychain-go",
    url = "https://github.com/bazel-contrib/supply-chain/releases/download/supply-chain-go-0.0.11/supply-chain-go-0.0.11.tar.gz",
)

bazel_dep(name = "apple_support", version = "2.11.0")  # provides --platforms=@apple_support//platforms:macos_x86_64
bazel_dep(name = "bazel_features", version = "1.54.1")
bazel_dep(name = "bazel_lib", version = "3.7.2")
bazel_dep(name = "bazel_skylib", version = "1.9.2")
bazel_dep(name = "gawk", version = "5.4.0.bcr.4")
bazel_dep(name = "gazelle", version = "0.54.0")
bazel_dep(name = "gcc_toolchain", version = "0.12.1")
bazel_dep(name = "libarchive", version = "3.8.1.bcr.3")
bazel_dep(name = "llvm", version = "0.8.26")
bazel_dep(name = "platforms", version = "1.1.0")
bazel_dep(name = "protobuf", version = "35.1")
bazel_dep(name = "re.bzl", version = "0.4.1")
bazel_dep(name = "rules_bison", version = "0.4.bcr.1")
bazel_dep(name = "rules_cc", version = "0.2.27")
bazel_dep(name = "rules_flex", version = "0.4.1")
bazel_dep(name = "rules_foreign_cc", version = "0.17.0")
bazel_dep(name = "rules_go", version = "0.65.0")
bazel_dep(name = "rules_m4", version = "0.3.bcr.1")
bazel_dep(name = "rules_multitool", version = "1.11.1")
bazel_dep(name = "rules_pkg", version = "1.3.0")
bazel_dep(name = "rules_python", version = "2.4.6")
bazel_dep(name = "rules_rs", version = "0.1.3")
bazel_dep(name = "rules_shell", version = "0.8.0")

# hermeticbuild/rules_wine v0.1.2 is not on the BCR yet.
bazel_dep(name = "rules_wine", version = "0.1.2")
archive_override(
    module_name = "rules_wine",
    sha256 = "e9905d00ce0dc5ca2b4c665d2cd6e632dd68d535de780b6c1aefda0d827888bf",
    strip_prefix = "rules_wine-0.1.2",
    urls = ["https://github.com/hermeticbuild/rules_wine/archive/refs/tags/v0.1.2.tar.gz"],
)

bazel_dep(name = "toml.bzl", version = "0.5.0")
bazel_dep(name = "toolchains_msvc", version = "0.1.0")
bazel_dep(name = "with_cfg.bzl", version = "1.0.2")

bazel_dep(name = "rules_testing", version = "0.9.0", dev_dependency = True)

single_version_override(
    module_name = "protobuf",
    patch_strip = 1,
    patches = [
        "//bazel/patches:protobuf-crate-universe-extensions.patch",  # protocolbuffers/protobuf#28230
    ],
    version = "35.1",
)

single_version_override(
    module_name = "rules_foreign_cc",
    patch_strip = 1,
    patches = [
        # https://github.com/bazel-contrib/rules_foreign_cc/pull/1452
        "//bazel/patches:rules_foreign_cc/0002-configure_make-provide-DY-LD_LIBRARY_PATH-based-on-t.patch",
        # https://github.com/bazel-contrib/rules_foreign_cc/pull/1491
        "//bazel/patches:rules_foreign_cc/0003-pass-j-flag-directly-on-make-command-line.patch",
        # https://github.com/bazel-contrib/rules_foreign_cc/issues/985
        # TODO(agent-build): Ideally we'd like to find a better way to solve this, possibly
        # finding a general solution that could be properly upstreamed
        "//bazel/patches:rules_foreign_cc/0004-Pass-cc-flags-as-CPPFLAGS.patch",
    ],
)

# Temporary until the following PRs (or equivalents) land
single_version_override(
    module_name = "rules_go",
    patch_strip = 1,
    patches = [
        # https://github.com/bazel-contrib/rules_go/pull/3977
        "//bazel/patches:rules_go-windows-symlink-workaround.patch",
        # https://github.com/bazel-contrib/rules_go/pull/4727
        "//bazel/patches:rules_go-link-resource-set.patch",
    ],
)

# The patch loads //bazel/toolchains:cc_toolchain_transition.bzl from the main repo.
# Drop once cc toolchains no longer inherit their consumer's configuration:
# https://github.com/hermeticbuild/hermetic-llvm/issues/895
single_version_override(
    module_name = "rules_cc",
    patch_strip = 1,
    patches = [
        "//bazel/patches:rules_cc-cc_toolchain-reset-go-settings.patch",
    ],
    version = "0.2.27",
)

# Fork of rules_pkg main carrying bazelbuild/rules_pkg#1089 (pkg_rpm
# rpm_own_tree_dirs). Go back to upstream main once it's merged.
archive_override(
    module_name = "rules_pkg",
    sha256 = "05ba3462560329bf6757b4369c238d6997f418e3eda3db0da41db3c6e939a8fb",
    strip_prefix = "rules_pkg-a0fea16700948eeefc885f23200e8e52d5e914eb",
    urls = ["https://github.com/chouquette/rules_pkg/archive/a0fea16700948eeefc885f23200e8e52d5e914eb.tar.gz"],
)

single_version_override(
    module_name = "rules_rs",
    patch_strip = 1,
    patches = [
        "//bazel/patches:rules_rs-windows-gnu.patch",
    ],
    version = "0.1.3",
)

##########################################
## Tools that ship with the OS and we wrap
##########################################

find_macos_codesign = use_repo_rule("//bazel/toolchains/codesign:configure.bzl", "find_macos_codesign")

find_macos_codesign(
    name = "macos_codesign",
    exec_compatible_with = ["@platforms//os:macos"],
)

find_macos_pkgbuild = use_repo_rule("//bazel/toolchains/pkgbuild:configure.bzl", "find_macos_pkgbuild")

find_macos_pkgbuild(
    name = "macos_pkgbuild",
    exec_compatible_with = ["@platforms//os:macos"],
)

find_selinux_tools = use_repo_rule("//bazel/toolchains/selinux_tools:configure.bzl", "find_selinux_tools")

find_selinux_tools(
    name = "selinux_tools",
    exec_compatible_with = ["@platforms//os:linux"],
)

register_toolchains(
    "@macos_codesign//:all",
    "@macos_pkgbuild//:all",
    "@selinux_tools//:all",
    dev_dependency = True,
)

register_toolchains(
    "//bazel/toolchains/dd_strip:linux_toolchain",
    "//bazel/toolchains/dd_strip:macos_toolchain",
    "//bazel/toolchains/dd_strip:windows_toolchain",
)

register_toolchains(
    "//bazel/rules/windows:linux_x86_64_toolchain",
    "//bazel/rules/windows:windows_toolchain",
)

#########################
## Prebuilt binaries   ##
#########################

http_archive(
    name = "com_github_bazelbuild_buildtools",
    patch_strip = 1,
    patches = [
        "//bazel/patches:buildifier-build.patch",  # bazel-contrib/buildtools#1398
        "//bazel/patches:buildifier-internal-factory.patch",  # bazel-contrib/buildtools#1399
        "//bazel/patches:buildifier-runner-bat-template.patch",  # bazel-contrib/buildtools#1399, #1400
    ],
    sha256 = "fa0b905032d49a621679e7318875736e451895a1417d992fbbebd27f82b83c38",
    strip_prefix = "buildtools-10.1.0",
    type = "tar.gz",
    urls = [
        "https://codeload.github.com/bazel-contrib/buildtools/tar.gz/refs/tags/v10.1.0",
        "https://github.com/bazel-contrib/buildtools/archive/refs/tags/v10.1.0.tar.gz",
    ],
)

# Upstream Linux kernel syscall tables, used by
# //pkg/security/utils:utils_syscall_table and
# //pkg/security/secl/model:syscall_table to regenerate
# pkg/security/utils/syscalls.go and
# pkg/security/secl/model/syscalls_linux_{amd64,arm64}.go.
# Bumping the kernel version requires updating the URLs and sha256 of both
# files together.
http_file(
    name = "linux_v6_13_syscall_64_tbl",
    sha256 = "a25d490b97e98fa2ad7912f229555e1c8f0e5ba70960f508ae4c324b2439aa04",
    urls = ["https://raw.githubusercontent.com/torvalds/linux/v6.13/arch/x86/entry/syscalls/syscall_64.tbl"],
)

http_file(
    name = "linux_v6_13_unistd_h",
    sha256 = "53b1df8caee4a4c2ff37d0ec895e22663a0e61b188de61b98f025709ba6c8e18",
    urls = ["https://raw.githubusercontent.com/torvalds/linux/v6.13/include/uapi/asm-generic/unistd.h"],
)

multitool = use_extension("@rules_multitool//multitool:extension.bzl", "multitool")
multitool.hub(lockfile = "//bazel:prebuilt_buildtools.json")
multitool.hub(lockfile = "//bazel:prebuilt_jq.json")
use_repo(multitool, "multitool")

register_toolchains(
    "//bazel/toolchains/patchelf:patchelf_built_toolchain",
    dev_dependency = True,
)

register_toolchains(
    "//bazel/toolchains/rpath_rewriter:install_name_tool_toolchain",
    "//bazel/toolchains/rpath_rewriter:noop_windows_toolchain",
    "//bazel/toolchains/rpath_rewriter:patchelf_toolchain",
)

find_rpmbuild = use_extension("@rules_pkg//toolchains/rpm:rpmbuild_configure.bzl", "find_system_rpmbuild_bzlmod", dev_dependency = True)
use_repo(find_rpmbuild, "rules_pkg_rpmbuild")

register_toolchains(
    "@rules_pkg_rpmbuild//:all",
    dev_dependency = True,
)

######################################
## LLVM BPF toolchain for eBPF    ##
####################################

llvm_bpf_ext = use_extension("//bazel/toolchains/llvm_bpf:llvm_bpf_configure.bzl", "llvm_bpf_extension")
llvm_bpf_ext.configure(
    clang_build_version = "v60409452-ee70de70",
    clang_version = "12.0.1",
    s3_base_url = "https://dd-agent-omnibus.s3.amazonaws.com/llvm",
    sha256s = {
        "clang.amd64": "2a4df4c49a57efb33ec4e51f87f837bc80f3a5874a5828384f265541a018394e",
        "clang.arm64": "5432ee1afc66453a457e756b025e4cace3aa56f687f595ac5d5bebcff00eac1b",
        "llc.amd64": "aa6ca65c28ac09f3ba1d22ccbda6a85d1414c6ed4491d8d758a08351cb66f86e",
        "llc.arm64": "08429823efd7d4ab6a247b195dabd0e8d8b43c50789704fd3a19947e71dd4776",
        "llvm-strip.amd64": "70a9edc44ccad32361f1c6ae619c3b98e5505d4b67f24b5996f55bf841ee5cbd",
        "llvm-strip.arm64": "1fd0cb6344d606d8c6fe6ea424fdfdd1cba1228f027dd3f08463c914bc47f67e",
    },
)
use_repo(llvm_bpf_ext, "llvm_bpf")

register_toolchains("@llvm_bpf//:llvm_bpf_toolchain")

## Linux kernel headers for eBPF prebuilt compilation
## Registers three repos: host auto-detect + explicit x86_64 + explicit aarch64
## for cross-compilation via --//bazel/rules/ebpf:target_arch=<arch>.
linux_headers_ext = use_extension("//bazel/toolchains/linux_headers:hermetic_linux_headers.bzl", "linux_headers_extension")

# snapshot.ubuntu.com is mirrored through the ADMS Bazel downloader.
linux_headers_ext.configure(
    arch_sha256s = {
        "aarch64": "bc6d614bc03a0bdbe35b2ab71a86118194f66a7f75d10f02d65e9eb30088ff2e",
        "x86_64": "00deb560f75ee2947f298ba687b386e3df920d8e3cca9dcd8eedc64c0755f42e",
    },
    arch_urls = {
        "aarch64": "https://snapshot.ubuntu.com/ubuntu/20260415T000000Z/pool/main/l/linux/linux-headers-6.8.0-110-generic_6.8.0-110.110_arm64.deb",
        "x86_64": "https://snapshot.ubuntu.com/ubuntu/20260415T000000Z/pool/main/l/linux/linux-headers-6.8.0-110-generic_6.8.0-110.110_amd64.deb",
    },
    common_sha256 = "fa7ec534c2fec2f287158073f1d9fe8f285ced726d5c1d040cb66f658fb5eba7",
    common_url = "https://snapshot.ubuntu.com/ubuntu/20260415T000000Z/pool/main/l/linux/linux-headers-6.8.0-110_6.8.0-110.110_all.deb",
    header_release = "6.8.0-110",
)
use_repo(linux_headers_ext, "linux_headers", "linux_headers_aarch64", "linux_headers_x86_64")

######################################
## Compilers and toolchains        ##
####################################

archive_override(
    module_name = "toolchains_msvc",
    patch_strip = 1,
    # Adds MSBuild + the VC project system, and whole-tree filegroups, so MSBuild-driven
    # builds (CPython) can run against the same hermetic toolchain as rules_cc.
    patches = ["//bazel/patches:toolchains_msvc/0001-hermetic-msbuild-and-toolchain-trees.patch"],
    sha256 = "1ab52698bd8b1eac2e005a07e25e62538daed471e9657586213b88d7cd7cb14d",
    strip_prefix = "toolchains_msvc-8e2aa4624bbb5a53a94f135e90995f307875d1ad",
    urls = ["https://github.com/Dragnalith/toolchains_msvc/archive/8e2aa4624bbb5a53a94f135e90995f307875d1ad.tar.gz"],
)

archive_override(
    module_name = "gcc_toolchain",
    patch_args = ["-p1"],
    patches = [
        "//bazel/patches:gcc-toolchain/0001-adapt-to-our-ctng-toolchain.patch",
        "//bazel/patches:gcc-toolchain/0002-fix-c-x86_64-header-locations-with-our-ctng-toolchai.patch",
        "//bazel/patches:gcc-toolchain/0003-add-nostdinc-to-asmflags.patch",
        "//bazel/patches:gcc-toolchain/0006-independent-exec-target-arch.patch",
    ],
    sha256 = "9602cf9a7f854a9a70758e6eac241e269996d2a1eb941479e8886f4ccf127412",
    strip_prefix = "gcc-toolchain-0.12.1",
    urls = ["https://github.com/f0rmiga/gcc-toolchain/releases/download/0.12.1/gcc-toolchain-0.12.1.tar.gz"],
)

gcc_toolchains = use_extension("@gcc_toolchain//toolchain:module_extensions.bzl", "gcc_toolchains", dev_dependency = True)
gcc_toolchains.toolchain(
    name = "gcc_toolchain_x86_64",
    binary_prefix = "x86_64-linux-gnu-",
    enable_fortran = False,
    extra_ldflags = ["-Wl,--build-id=sha1"],
    gcc_version = "11.4.0",
    target_arch = "x86_64",
)
gcc_toolchains.toolchain(
    name = "gcc_toolchain_aarch64",
    binary_prefix = "aarch64-linux-gnu-",
    enable_fortran = False,
    extra_ldflags = ["-Wl,--build-id=sha1"],
    gcc_version = "12.3.0",
    target_arch = "aarch64",
)

# Cross toolchain: runs on aarch64, targets armv7 (armhf). No native armv7 CI
# runners exist, so unlike the other two entries this always cross-compiles.
gcc_toolchains.toolchain(
    name = "gcc_toolchain_armv7",
    binary_prefix = "arm-linux-gnueabihf-",
    enable_fortran = False,
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:aarch64",
    ],
    gcc_version = "13.2.0",
    gcc_versions = """{"13.2.0": {"armv7": {
        "url": "https://dd-agent-build-artifacts.s3.amazonaws.com/toolchains/main/0cd6ae2749998d738188f10abfbdeb186d76a16d4c3f5c814d69bbc3c1757fea/aarch64/arm-linux-gnueabihf-gcc.tar.xz",
        "sha256": "2f6171e4411c51626ecc857d85dcb25c1b886807272d5b951fac128d31e858d3"
    }}}""",
    target_arch = "armv7",
)
use_repo(gcc_toolchains, "gcc_toolchain_x86_64")
use_repo(gcc_toolchains, "gcc_toolchain_aarch64")
use_repo(gcc_toolchains, "gcc_toolchain_armv7")

llvm_toolchain = use_extension("@llvm//extensions:toolchain.bzl", "toolchain")
llvm_toolchain.exec(
    arch = "aarch64",
    os = "linux",
)
llvm_toolchain.exec(
    arch = "aarch64",
    os = "macos",
)
llvm_toolchain.exec(
    arch = "x86_64",
    os = "linux",
)
llvm_toolchain.exec(
    arch = "x86_64",
    os = "macos",
)
llvm_toolchain.target(
    arch = "aarch64",
    os = "macos",
)
llvm_toolchain.target(
    arch = "x86_64",
    os = "macos",
)
llvm_toolchain.target(
    arch = "x86_64",
    os = "windows",
)
use_repo(llvm_toolchain, "llvm_toolchains")

osx = use_extension("@llvm//extensions:osx.bzl", "osx")
osx.frameworks(names = [
    "CFNetwork",  # CoreServices and Foundation headers
    "CoreFoundation",  # default
    "CoreGraphics",  # Foundation headers
    "CoreServices",  # pkg/notableevents
    "DiskArbitration",  # CoreServices headers
    "Foundation",  # default
    "IOKit",  # battery and thermal checks, inventory systeminfo
    "Kernel",  # default
    "OSLog",  # default
    "Security",  # default
    "SystemConfiguration",  # default
])
osx.libraries(names = ["libpcap"])  # gopacket/pcap

# Hermetic MinGW-w64 toolchain sourced from a pinned WinLibs distribution.
# Variant: GCC 14.2.0 + MinGW-w64 12.0.0, POSIX threads, MSVCRT runtime,
# no LLVM bundle. URL, sha256 and gcc_version must move together when bumping.
winlibs_mingw_repository = use_repo_rule(
    "//bazel/toolchains/mingw:winlibs.bzl",
    "winlibs_mingw_repository",
)

winlibs_mingw_repository(
    name = "winlibs_mingw64",
    gcc_version = "14.2.0",
    sha256 = "ff475e985a98c5f3785129baf7460db14fee27708bce35f2833db5009507f1b9",
    urls = [
        "https://github.com/brechtsanders/winlibs_mingw/releases/download/14.2.0posix-19.1.7-12.0.0-msvcrt-r3/winlibs-x86_64-posix-seh-gcc-14.2.0-mingw-w64msvcrt-12.0.0-r3.zip",
        "https://downloads.sourceforge.net/project/winlibs-mingw/14.2.0posix-19.1.7-12.0.0-msvcrt-r3/winlibs-x86_64-posix-seh-gcc-14.2.0-mingw-w64msvcrt-12.0.0-r3.zip",
    ],
)

# Hermetic MSVC + Windows SDK + MSBuild for CPython and DatadogInterop
# (see deps/cpython/build_python.bat, tools/windows/DatadogInterop). MinGW stays
# the default Windows cc_toolchain.
msvc_toolchain = use_extension("@toolchains_msvc//:extensions.bzl", "toolchain")
msvc_toolchain.toolchain_set(
    name = "default",
    # MSVC toolset version, not VS product version: VS 2022 17.14.x → 14.44
    # (see https://learn.microsoft.com/en-us/cpp/overview/compiler-versions).
    # toolchains_msvc only accepts 14.xx here, not 17.14.
    msvc_versions = ["14.44"],
    # Win11 SDK 10.0.26100; toolchains_msvc uses the trailing build number only.
    winsdk_versions = ["26100"],
)
use_repo(msvc_toolchain, "msvc_toolchains")

# TODO{agent-build}: Find a way to register platform-specific toolchains dynamically
register_toolchains(
    "@gcc_toolchain_x86_64//:cc_toolchain",
    "@gcc_toolchain_aarch64//:cc_toolchain",
    "@gcc_toolchain_armv7//:cc_toolchain",
    "@winlibs_mingw64//:mingw_cc_toolchain",
    "@msvc_toolchains//:all",
    "@llvm_toolchains//:all",  # last to avoid taking precedence over GCC toolchains
)

# =========================================
# Python dependencies
# =========================================

# Keep in sync with .python-version
PYTHON_VERSION = "3.12"

python_config = use_extension("@rules_python//python/extensions:config.bzl", "config")
python_config.explicit_init_py(default = True)

python = use_extension("@rules_python//python/extensions:python.bzl", "python")
python.defaults(python_version_file = "//:.python-version")
use_repo(python, "pythons_hub", "python_" + PYTHON_VERSION.replace(".", "_"))

pip = use_extension("@rules_python//python/extensions:pip.bzl", "pip")

# Development requirements. These are the tools needed to build the agent.
# TODO: Make a distinct set for modules we redistribute with the agent.
pip.parse(
    hub_name = "py_dev_requirements",
    python_version = PYTHON_VERSION,
    requirements_lock = "//deps:py_dev_requirements_lock.txt",
    # Resolve wheels for all platforms, not just the host's, to allow cross-platform (e.g. macOS -> Linux RBE) builds.
    target_platforms = [
        "linux_aarch64",
        "linux_x86_64",
        "osx_aarch64",
        "osx_x86_64",
        "windows_x86_64",
    ],
)
pip.parse(
    hub_name = "py_agent_integrations_tool_requirements",
    python_version = PYTHON_VERSION,
    requirements_lock = "//deps:py_agent_integrations_tool_requirements_lock.txt",
)
use_repo(pip, "py_agent_integrations_tool_requirements", "py_dev_requirements")

#######################
## Rust dependencies ##
#######################

toolchains = use_extension("@rules_rs//rs/toolchains:module_extension.bzl", "toolchains")
toolchains.toolchain(
    edition = "2024",
    use_rust_redist = False,  # rust-redist lacks the GNU-hosted Windows archives our patch needs
    version = "1.94.0",
)
use_repo(toolchains, "default_rust_toolchains")

register_toolchains("@default_rust_toolchains//...")

rules_rust_shim = use_extension("@rules_rs//rs:rules_rust.bzl", "rules_rust")
use_repo(rules_rust_shim, "rules_rust")

rules_rust_prost_shim = use_extension("@rules_rs//rs:rules_rust_prost.bzl", "rules_rust_prost")
use_repo(rules_rust_prost_shim, "rules_rust_prost")

register_toolchains("//bazel/toolchains/prost:prost_toolchain")

include("//deps:crates.MODULE.bazel")

#########################
## Native dependencies ##
#########################

# Make our 3rd parties depencency repositories known
# bazel mod tidy command adds a new line between includes.
# buildifier eliminates them. If we treat mod tidy as a code formatter
# for MODULE.bazel, we need to leave-alone the includes so that buildifier
# doesn't fail nor re-format them.
# buildifier: leave-alone
include("//deps:repos.MODULE.bazel")

# buildifier: leave-alone
include("//deps/openssl:openssl_sys.MODULE.bazel")

# buildifier: leave-alone
include("//deps/acl:acl.MODULE.bazel")

# buildifier: leave-alone
include("//deps/agent_data_plane:agent_data_plane.MODULE.bazel")

# buildifier: leave-alone
include("//deps/cacerts:cacerts.MODULE.bazel")

# buildifier: leave-alone
include("//deps/compile_policy:compile_policy.MODULE.bazel")

# buildifier: leave-alone
include("//deps/cpython:cpython.MODULE.bazel")

# buildifier: leave-alone
include("//deps/curl:curl.MODULE.bazel")

# buildifier: leave-alone
include("//deps/freetds:freetds.MODULE.bazel")

# buildifier: leave-alone
include("//deps/gstatus:gstatus.MODULE.bazel")

# buildifier: leave-alone
include("//deps/jmxfetch:jmxfetch.MODULE.bazel")

# buildifier: leave-alone
include("//deps/nfsiostat:nfsiostat.MODULE.bazel")

# buildifier: leave-alone
include("//deps/openscap:openscap.MODULE.bazel")

# buildifier: leave-alone
include("//deps/libpcap:libpcap.MODULE.bazel")

# buildifier: leave-alone
include("//deps/security_agent_policies:security_agent_policies.MODULE.bazel")

# buildifier: leave-alone
include("//deps/setuptools:setuptools.MODULE.bazel")

# buildifier: leave-alone
include("//deps/snmp_traps:snmp_traps.MODULE.bazel")

# buildifier: leave-alone
include("//deps/windows:drivers.MODULE.bazel")

# buildifier: leave-alone
include("//deps/msodbcsql18:msodbcsql18.MODULE.bazel")

# buildifier: leave-alone
include("//deps:go.MODULE.bazel")

# buildifier: leave-alone
include("//deps/agent_integrations:integrations.MODULE.bazel")

rules_wine_ext = use_extension("@rules_wine//wine/extension:wine.bzl", "wine")
use_repo(rules_wine_ext, "wine_toolchains")

register_toolchains("@wine_toolchains//:all")

# Same Wine tag the rules_wine prebuilt is built from. wmc is not in that
# runtime archive, so the resource toolchain compiles it from this tree.
wine_wmc_repository(
    name = "wine_wmc",
    build_file = "//bazel/tools/wmc:overlay/wmc.BUILD.bazel",
    config_h = "//bazel/tools/wmc:overlay/config.h",
    sha256 = "98b21b4ebdf7d9e2baa4a3508514285cf449f455603f82d3364b014c0e79b793",
    strip_prefix = "wine-wine-11.20",
    urls = ["https://codeload.github.com/wine-mirror/wine/tar.gz/refs/tags/wine-11.20"],
)

use_extension("//bazel/tools:bazelisk_check.bzl", "bazelisk_check")